Definir visualização de barras para folhas de um livro - JJoão (08/2007)

Dúvida: Preciso que a barra de fórmulas, status e das guias da planilha não apareçam em uma determinada planilha do meu arquivo. A solução para resolver o problema acima, não pode eliminar as barras do restante das planilhas do arquivo e nem em outros arquivos que possam estar abertos. - Robson Carmello

Duas macros que em conjunto com alguns eventos irão esconder ou mostrar as barras escolhidas.
Para configurar com que folhas se quer esconder as barras, coloca-se o seu index (numero) na macro "Config_visual"

Exemplo:
as_folhas = Array(1, 2) 'folhas para esconder barras

O Código VBA deve ser colocado dentro do ThisWorkbook" ou "EsteLivro" (conforme o idioma), ver figura abaixo.

Option Explicit

Private Sub Workbook_SheetActivate(ByVal Sh As Object)
    Config_visual Sh.Index
End Sub

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object)
    Config_visual Sh.Index
End Sub

Private Sub Workbook_WindowActivate(ByVal Wn As Window)
    Config_visual ActiveSheet.Index
End Sub

Private Sub Workbook_WindowDeactivate(ByVal Wn As Window)
    DisplayOnOff True
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    DisplayOnOff True
End Sub

Private Sub Config_visual(i As Integer)
    Dim as_folhas, Visualizar As Boolean, s As Integer
    Visualizar = True
    as_folhas = Array(1, 2) 'folhas para esconder barras
    
    For s = LBound(as_folhas) To UBound(as_folhas)
       If i = as_folhas(s) Then
          Visualizar = False
          Exit For
       End If
    Next s
    
    DisplayOnOff Visualizar
    
End Sub

Private Sub DisplayOnOff(status As Boolean)
      
   With ActiveWindow
        .DisplayHeadings = status
        .DisplayWorkbookTabs = status
   End With
    
   With Application
       .DisplayFormulaBar = status
       .DisplayStatusBar = status
   End With
      
End Sub